Code 1

option reslim=1000000, limrow=10000, limcol=0, solprint=on, solvelink=2;

SET I seasons /I1\*I4/

N all possible locations /00000\*99999/

ST\_ALL state labels /01\*56/

ST(ST\_ALL) actual states

/

01 Alabama

\* 02 Alaska

04 Arizona

05 Arkansas

06 California

08 Colorado

09 Connecticut

10 Delaware

11 District of Columbia

12 Florida

13 Geogia

\* 15 Hawaii

16 Idaho

17 Illinois

18 Indiana

19 Iowa

20 Kansas

21 Kentucky

22 Louisiana

23 Maine

24 Maryland

25 Massachusetts

26 Michigan

27 Minnesota

28 Mississippi

29 Missouri

30 Montana

31 Nebraska

32 Nevada

33 New Hampshire

34 New Jersey

35 New Mexico

36 New York

37 North Carolina

38 North Dakota

39 Ohio

40 Oklahoma

41 Oregon

42 Pennsylvania

44 Rhode Island

45 South Carolina

46 South Dakota

47 Tennessee

48 Texas

49 Utah

50 Vermont

51 Virginia

53 Washington

54 West Virginia

55 Wisconsin

56 Wyoming

/

F(N) production locations

S(N) hub locations

C capacity levels /C1\*C4/

ALIAS (C,CC)

ALIAS (N,NN)

SET REG /AP,CB,DL,LA,MN,NP,PA,SE,SP,NE/;

SET ST\_REG(REG,ST) /

SE.01 Alabama

MN.04 Arizona

DL.05 Arkansas

PA.06 California

MN.08 Colorado

NE.09 Connecticut

NE.10 Delaware

NE.11 District of Columbia

SE.12 Florida

SE.13 Geogia

MN.16 Idaho

CB.17 Illinois

CB.18 Indiana

CB.19 Iowa

NP.20 Kansas

AP.21 Kentucky

DL.22 Louisiana

NE.23 Maine

NE.24 Maryland

NE.25 Massachusetts

LA.26 Michigan

LA.27 Minnesota

DL.28 Mississippi

CB.29 Missouri

MN.30 Montana

NP.31 Nebraska

MN.32 Nevada

NE.33 New Hampshire

NE.34 New Jersey

MN.35 New Mexico

NE.36 New York

AP.37 North Carolina

NP.38 North Dakota

CB.39 Ohio

SP.40 Oklahoma

PA.41 Oregon

NE.42 Pennsylvania

NE.44 Rhode Island

SE.45 South Carolina

NP.46 South Dakota

AP.47 Tennessee

SP.48 Texas

MN.49 Utah

NE.50 Vermont

AP.51 Virginia

PA.53 Washington

AP.54 West Virginia

LA.55 Wisconsin

MN.56 Wyoming

/

PARAMETER p(I,N) production plus imports

d(N,N) distance from production loc to hub loc

t fixed transportation cost

U1(C) max capacity

U2(C) min capacity

h0(C) fixed cost h0

h1(C) variable cost h1

;

$offlisting

SET STN(ST\_ALL,N) /

$include states\_index.inc

/;

\* Read impedance/distance matrix

$gdxin sourcedata.gdx

$load d

$load f

$load s

\* Read production data

parameters

p1(N) season 1 prod /

$include Q1\_sep23.inc

/

p2(N) season 2 prod /

$include Q2\_sep23.inc

/

p3(N) season 3 prod /

$include Q3\_sep23.inc

/

p4(N) season 4 prod /

$include Q4\_sep23.inc

/ ;

$onlisting

\* Create single production matrix

p('I1',N) = p1(N);

p('I2',N) = p2(N);

p('I3',N) = p3(N);

p('I4',N) = p4(N);

SET OK(N,N);

\* fixed cost ($ per hub)

h0('C1') = 11334748;

h0('C2') = 4959865;

h0('C3') = 1066686;

h0('C4') = 470116;

\* variable cost ($ per ton)

h1('C1') = 53.41;

h1('C2') = 54.57;

h1('C3') = 62.40;

h1('C4') = 65.71;

\* capacity (ton)

U1('C1') = 3500000;

U1('C2') = 1600000;

U1('C3') = 700000;

U1('C4') = 300000;

U2(C) = U1(C+1) + 0.00001;

\*U1(C) = 3500000;

\*scale costs

h0(C) = h0(C)/1e6;

h1(C) = h1(C)/1e6;

\* transport cost ($/mile/ton)

t=0.08/1e6;

\* active subsets for reduced model

set STG(ST\_ALL), FG(N), SG(N)

POSITIVE VARIABLE x(C,N,N)

PARAMETER z0(C,N)

BINARY VARIABLE z(C,N)

VARIABLE TC;

EQUATIONS obj\_primal, supplys, uppers, lowers, unique,ux

;

\* Primal formulation

obj\_primal.. TC =E= SUM((C,SG), h0(C)\*z(C,SG))

+ SUM((C,OK), h1(C)\*x(C,OK))

+ SUM((C,OK), d(OK)\*t\*x(C,OK))

;

supplys(FG).. SUM((C,SG), x(C,FG,SG)$OK(FG,SG)) =G= SUM(I, p(I,FG));

uppers(C,SG).. SUM(FG, x(C,FG,SG)$OK(FG,SG)) =L= U1(C)\*z(C,SG) ;

lowers(C,SG).. SUM(FG, x(C,FG,SG)$OK(FG,SG)) =G= U2(C)\*z(C,SG) ;

unique(SG).. SUM(C, z(C,SG)) =L= 1;

MODEL hubs\_primal /obj\_primal, supplys, uppers, unique/ ;

$onecho > cplex.op2

eprhs=1E-9

mipemphasis=2

parallelmode=-1

threads=2

$offecho

hubs\_primal.optfile=2;

PARAMETER report, z0\_reg,

max\_dist maximum distance source for each hub

hub\_sources number of sources shipping to selected hub;

option optcr=0.05;

LOOP(REG$(ord(REG) = 5),

\* all hubs eligible

SG(S)=YES;

\* select only sources that are in current REG

STG(ST)=NO;

\* States that are in current Region

STG(ST)$ST\_REG(REG,ST)=YES;

\* sources that are in allowed States

FG(F)=NO;

FG(F)=YES$SUM(STG, 1$STN(STG,F));

\* Define active subset of source/hub possibilities

\* In this case all non-zero links in the impedance matrix

OK(F,S)=NO;

OK(FG,SG)=YES$d(FG,SG);

option optcr=0.05;

solve hubs\_primal using MIP minimizing TC ;

\*submodel details

report(REG,'model','rMIP obj')=hubs\_primal.objEst;

report(REG,'model','equations')=hubs\_primal.numEqu;

report(REG,'model','discrete variables')=hubs\_primal.numDVar;

report(REG,'model','all variables')=hubs\_primal.numVar;

report(REG,'model','non-zeros')=hubs\_primal.numNZ;

report(REG,'model','sources')=SUM(F, 1$FG(F));

report(REG,'model','paths')=SUM((FG,SG), 1$OK(FG,SG));

\*solution delatils

report(REG,'soln','TC')=TC.L;

report(REG,'time','resusd')=hubs\_primal.resusd;

report(REG,'soln','fcost')= SUM((C,SG), h0(C)\*z.L(C,SG));

report(REG,'soln','vcost')= SUM((C,OK), h1(C)\*x.L(C,OK));

report(REG,'soln','tcost')= SUM((C,OK), d(OK)\*t\*x.L(C,OK));

max\_dist(REG,SG)= SMAX(FG, d(FG,SG)\*SUM(C, z.L(C,SG))$OK(FG,SG));

hub\_sources(REG,SG)= SUM(FG, 1$SUM(C, x.L(C,FG,SG)\*z.L(C,SG)));

\*hub assignment

z0\_reg(REG,C,S)=z.L(C,S);

);

Code 2

SET I seasons /I1\*I4/

N all possible locations /00000\*99999/

F(N) production locations

S(N) hub locations

C capacity levels /C1\*C4/

ALIAS (C,CC)

ALIAS (N,NN)

PARAMETER p(I,N) production plus imports

d distance from production loc to hub loc

t fixed transportation cost

U1(C,N) max capacity

U2(C,N) min capacity

h0(C) fixed cost h0

h1(C) variable cost h1

;

\* Read impedance/distance matrix

$gdxin sourcedata.gdx

$load d

\* Read production data

parameters

p1(N) season 1 prod /

$include Q1\_sep23.inc

/

p2(N) season 2 prod /

$include Q2\_sep23.inc

/

p3(N) season 3 prod /

$include Q3\_sep23.inc

/

p4(N) season 4 prod /

$include Q4\_sep23.inc

/ ;

\* Create single production matrix

p('I1',N) = p1(N);

p('I2',N) = p2(N);

p('I3',N) = p3(N);

p('I4',N) = p4(N);

\* Define active production and hub locations based on data

F(N)=NO;

S(N)=NO;

F(N)$SUM(NN , d(N,NN)) =YES;

\* Note: this gives a slightly smaller set of potential hub locations.

\* It could be read directly

S(N)$SUM(NN , d(NN,N)) =YES;

\*F(N)$SUM(I ,p(I,N)) =YES;

\*S(N)$F(N) = YES;

h0('C1') = 11334748;

h0('C2') = 4959865;

h0('C3') = 1066686;

h0('C4') = 470116;

h1('C1') = 53.41;

h1('C2') = 54.57;

h1('C3') = 62.40;

h1('C4') = 65.71;

U1('C1') = 3500000;

U1('C2') = 1600000;

U1('C3') = 700000;

U1('C4') = 300000;

U2(C) = U1(C-1) + 1;

t=0.08;

POSITIVE VARIABLE x(I,N,N)

PARAMETER z0(C,N)

BINARY VARIABLE z(C,N)

VARIABLE TC;

EQUATIONS obj, supply, unique, upper, lower;

obj.. TC =E= SUM((C,S), h0(C)\*z(C,S))

+ SUM(C, h1(C)\*SUM((I,F,S)$d(f,s), x(I,F,S)))

+ SUM((I,F,S)$d(f,s), x(I,F,S)\*d(F,S)\*t);

supply(I,F).. SUM(S, x(I,F,S)) =E= p(I,F);

upper(I,S).. SUM(F$d(f,s), x(I,F,S)) =L= SUM(C, U1(C)\*z(C,S)) ;

lower(I,S).. SUM(F$d(f,s), x(I,F,S)) =G= SUM(C, U2(C)\*z(C,S)) ;

unique(S).. SUM(C, z(C,S)) =L= 1;

MODEL hubs\_init /obj, supply, unique, upper, lower/ ;

solve hubs\_init using MIP minimizing TC;